perimeter calculation

[CAD]

I hate listing each value using the "LIST" command then adding them after.

 

Is there any other easy way to add up perimeters of multiple objects? I'm using ACAD2000.

 

Thanks,

Robin

[Chaz]

You can draw a polygon around each object and do area sq. ftg, in the add mode. It will show you the area and perimeter ftg. You can also join all the polygons, (modify) and total the ftg. that way. I hope this was what you wanted.

[CAD]

Thanks Chaz, I'm sure it'll do but I need something that lets me select all the polylines then automatically adds up all its lengths.

 

I think I already found what I need (Google did it again!) Here's the lisp I found, i hope it could be useful:

 

;|

 

TLEN.LSP - Total LENgth of selected objects

© 1998 Tee Square Graphics

 

|;

 

(defun C:TLEN (/ ss tl n ent itm obj l)

(setq ss (ssget)

tl 0

n (1- (sslength ss)))

(while (>= n 0)

(setq ent (entget (setq itm (ssname ss n)))

obj (cdr (assoc 0 ent))

l (cond

((= obj "LINE")

(distance (cdr (assoc 10 ent))(cdr (assoc 11 ent))))

((= obj "ARC")

(* (cdr (assoc 40 ent))

(if (minusp (setq l (- (cdr (assoc 51 ent))

(cdr (assoc 50 ent)))))

(+ pi pi l) l)))

((or (= obj "CIRCLE")(= obj "SPLINE")(= obj "POLYLINE")

(= obj "LWPOLYLINE")(= obj "ELLIPSE"))

(command "_.area" "_o" itm)

(getvar "perimeter"))

(T 0))

tl (+ tl l)

n (1- n)))

(alert (strcat "Total length of selected objects is " (rtos tl)))

(princ)

)

 

cya :angewink: