Detatch Objects

[Devin Johnston]

I have a glass curtain wall that is one object but I need to break it up so that each pane of glass is an individual object without spending hours detaching each pane of glass. Does anyone know of a script that will do this?

[Dave Buchhofer]

toolTip="ExplodeElements to seperate objects"
buttonText="ExplodeElements to seperate objects"

--start macro

--- maxscript ExplodeElements

--- author: andrei kletskov (111) - http://andklv.narod.ru - andklv@mail.ru
--- description: this script explodes ojects' elements into separate objects
--- v0.1 - (22 july 2008) - initial version
--- v0.2 - (20 oct 2008) - complete new algorythm in attempt to speed-up



undo on
(
coll = #()
for obj in selection do
(
	try
	(
	convertTo obj PolyMeshObject
	c = 0
		while obj.faces.count > 0 do
		(
			c = c + 1
			el = polyOp.getElementsUsingFace obj obj.faces[1]
			polyOp.detachFaces obj el delete:true asNode:true name:(obj.name + "_EE_" +(c as string))
		)

		append coll obj
	)
	catch
	(
		print ("error processing: " + (obj.name as string))
	)
)
delete coll
)

[Devin Johnston]

Dave that's exactly what I needed that's so much, did you write it?

[Devin Johnston]

Dave is there a way to get it to re center the pivot point of each object so that each new object has it's own center?

[Dave Buchhofer]

That was a found script one day when i was doing something similar, the guy has quite a few useful snips on his site (its in the comments of the script)

 

after the fact to center pivots you can just run this script to do that:

 

centerpivot $

 

I believe you can do it with the UI also, but i use it often enough that i made it a macroscript for hotkeying heh.

[Devin Johnston]

Yes your right the UI does all for this, thanks again!